[kirazeez23]

Hey bin noch etwas neu auf der Seite, und weiß nicht ob ich hier richtig bin für dieses Problem. Ich würde gerne wissen wie ein aivar aussehen würde, um ein NPC den Spieler angreifen zulassen wenn er etwas stiehlt aus einem Haus. Ich habe schon in den originalscripten reingeschaut aber Verwendung von solchem aivar finde ich dort leider nicht.

[Arthonius]

Da brauchst du in den NPC-Skripten nichts einstellen, das Angreifen nach Diebstahl machen NPCs automatisch in Portalräumen.

[kirazeez23]

ahh prima damit hat sich dann das geklärt. Ich hätte da noch eine Frage undzwar wollte ich den Held eskortieren lassen von einem NPC
und hatte das auch schon öfters getan nur hab ich jetzt ein kleines Problemchen bei diesem Script und finde das Problem nicht. Laut meinen Augen müsste das funktionieren.

var int Edgor_Los;


Instance DIA_Edgor_Baronheil (C_INFO)
{
    npc = NONE_99001_Edgor;
    nr = 1;
    condition = DIA_Edgor_Baronheil_Condition;
    information = DIA_Edgor_Baronheil_Info;
    description = "Ich bin bereit";
};


Func int DIA_Edgor_Baronheil_Condition()
{


    return TRUE;


};


Func void DIA_Edgor_Baronheil_Info()
{
    AI_Output (other, self, "DIA_Edgor_Baronheil_15_0"); //Ich bin bereit.
    AI_Output (self, other, "DIA_Edgor_Baronheil_7_1"); //Na dann wollen wir mal. Bleib hinter mir, ich hör schon wieder diese dreckigen Ratten.
    Edgor_Los = TRUE;
    AI_StopProcessInfos (self);
    
    self.aivar[AIV_PARTYMEMBER] = TRUE;
    Npc_ExchangeRoutine (self, "GuidezumHeilkraut");


    MIS_Baron = LOG_RUNNING;    
    Log_CreateTopic (TOPIC_Baron, LOG_MISSION);
    Log_SetTopicStatus(TOPIC_Baron, LOG_RUNNING);
    B_LogEntry (TOPIC_Baron,".....");
    
};

instance NONE_99001_Edgor (Npc_Default)
{
    // ------ NSC ------
    name         = "Edgor";
    guild         = GIL_NONE;
    id             = 99000;
    voice         = 7;
    flags       = 0;    //NPC_FLAG_IMMORTAL oder 0
    npctype        = NPCTYPE_MAIN;
    
    
        //-----------AIVARS----------------
aivar[AIV_NPCIsRanger] = TRUE;
    
    
    // ------ Attribute ------
    B_SetAttributesToChapter (self, 3);                                                                    //setzt Attribute und LEVEL entsprechend dem angegebenen Kapitel (1-6)
    attribute[ATR_STRENGTH]  =55;
        attribute[ATR_DEXTERITY] =75;
        attribute[ATR_MANA_MAX]  =100;
        attribute[ATR_MANA]      =100;
        attribute[ATR_HITPOINTS_MAX]=255;
        attribute[ATR_HITPOINTS]=255;
    
    // ------ Kampf-Taktik ------
    fight_tactic        = FAI_HUMAN_STRONG;    // MASTER / STRONG / COWARD
    
    // ------ Equippte Waffen ------                                                                    //Munition wird automatisch generiert, darf aber angegeben werden
    EquipItem            (self, ItMw_1h_Mil_Sword);
    EquipItem           (self, ItRw_Bow_L_03);
    
    // ------ Inventory ------
    B_CreateAmbientInv     (self);
        
    // ------ visuals ------                                                                            //Muss NACH Attributen kommen, weil in B_SetNpcVisual die Breite abh. v. STR skaliert wird
    B_SetNpcVisual         (self, MALE, "Hum_Head_Bald", Face_N_Homer, BodyTex_B, ITAR_LESTER);    
    Mdl_SetModelFatness    (self, 1);
    Mdl_ApplyOverlayMds    (self, "Humans_Tired.mds"); // Tired / Militia / Mage / Arrogance / Relaxed


    // ------ NSC-relevante Talente vergeben ------
    B_GiveNpcTalents (self);
    
    // ------ Kampf-Talente ------                                                                        //Der enthaltene B_AddFightSkill setzt Talent-Ani abhängig von TrefferChance% - alle Kampftalente werden gleichhoch gesetzt
    B_SetFightSkills (self, 30); //Grenzen für Talent-Level liegen bei 30 und 60i
    
    Mdl_ApplyOverlayMds     (self,    "Humans_BowT1.mds");
    Mdl_ApplyOverlayMds     (self,    "humans_1hST1.mds");


    // ------ TA anmelden ------
    daily_routine         = Rtn_Start_99001;
};


FUNC VOID Rtn_Start_99001 ()
{
    TA_Stand_WP                 (08,00,15,00,"WP_STAND_EDGOR_01");
    TA_Stand_ArmsCrossed                  (15,00,22,00,"WP_WALK_EDGOR_02");    
    TA_Stand_Eating                     (22,00,08,00,"WP_EAT_EDGOR_03");    
};


FUNC VOID Rtn_GuidezumHeilkraut_99001 ()
{
    TA_Guide_Player                  (08,00,23,00,"NW_OUTDOOR_HEALHERB_05");
    TA_Guide_Player                 (23,00,08,00,"NW_OUTDOOR_HEALHERB_05");        
};

Editiert: Jetzt grad wo ich noch paar mal drüber geschaut habe ist mir aufgefallen, dass ich die falsche ID benutzt hatte. Jetzt funktioniert alles sauber.
Und ich war mir so sicher alles 3 mal überprüft zuhaben... (facepalm)