[bister77]

Hallo,

konnte endlich zu Lutero nachdem ich von jedem Händer nur 1 Gold für meine Sachen bekommen habe und wollte bei ihm das Feilschen erlernen, jedoch hab ich keine Sprachoption dafür.

Jemand eine Idee?

[Road-runner]

Hallo,

ich habe das selbe Problem, hatte einen alten Spielstand da war alles okay.
Wenn ich jetzt (schätze Seit Hotfix 3) mit Lutero das erste mal rede hat er sein "normales" Inventar und bringt Feilschen nicht mehr bei.

Kann sich bitte jemand der sich damit auskennt mal die Datei von Hotfix 3 anschauen?
Ich weiß leider nicht wie das geht und mit Lutero neu herbeicheaten löst das Problem leider nicht.

Hab es jetzt auch nochmal ausprobiert und neu Installiert einmal ohne Hotfix und einmal nur mit dem ersten Hotfix.
Jeweils zu Lutero gecheatet und es ausprobiert, Problem besteht weiterhin.
Wenn jemand was dazu weiß wäre ich sehr dankbar.

Falls es hilft hier nochmal das Inventar: (Habe auch Bilder, weiß nur nicht wie man sie hier hochlädt)

Mit Problemen: Trank der Geschwindigkeit, Feldknöterich, Vergessen, Mincrawlerzange, Fackel(x10), Apfeltabak, Kohle, geweihtes Wasser, Pech, Quartz, Schwefel
(Müsste er aus DNDR nicht die 2 Bücher haben?)

Ohne Probleme: Degen der Banditen, Gehstock, Heiltrank, Trank der Geschwindigkeit(x6),Feldknöterich(x4), Vergessen(3x), Schlaf, Doppelblock, Einhandbuch, Blutfliegenstachel, Fackel(x10), Aqamarin, Kohle, geweihtes Wasser(x2), Erz(x2), Pech, Quartz(x4), Schwefel

(ohne Mengenangabe= 1)

[ZeroLord]

Hallo,

ich habe das selbe Problem, hatte einen alten Spielstand da war alles okay.
Wenn ich jetzt (schätze Seit Hotfix 3) mit Lutero das erste mal rede hat er sein "normales" Inventar und bringt Feilschen nicht mehr bei.

Kann sich bitte jemand der sich damit auskennt mal die Datei von Hotfix 3 anschauen?
Ich weiß leider nicht wie das geht und mit Lutero neu herbeicheaten löst das Problem leider nicht.

Hab es jetzt auch nochmal ausprobiert und neu Installiert einmal ohne Hotfix und einmal nur mit dem ersten Hotfix.
Jeweils zu Lutero gecheatet und es ausprobiert, Problem besteht weiterhin.
Wenn jemand was dazu weiß wäre ich sehr dankbar.

Falls es hilft hier nochmal das Inventar: (Habe auch Bilder, weiß nur nicht wie man sie hier hochlädt)

Mit Problemen: Trank der Geschwindigkeit, Feldknöterich, Vergessen, Mincrawlerzange, Fackel(x10), Apfeltabak, Kohle, geweihtes Wasser, Pech, Quartz, Schwefel
(Müsste er aus DNDR nicht die 2 Bücher haben?)

Ohne Probleme: Degen der Banditen, Gehstock, Heiltrank, Trank der Geschwindigkeit(x6),Feldknöterich(x4), Vergessen(3x), Schlaf, Doppelblock, Einhandbuch, Blutfliegenstachel, Fackel(x10), Aqamarin, Kohle, geweihtes Wasser(x2), Erz(x2), Pech, Quartz(x4), Schwefel

(ohne Mengenangabe= 1)

ist dieses problem noch da und falls ja gibt es dafür bereits einen fix (per spine wär am besten)
wollte hiver ma wieder anfangen hab aber gleich am anfang gestoppt als ich dieses thema hier gelesen hatte und wollte nicht 100h investiren nur um falls ein hotfix noch kommen sollte nochmal anfangen zu müssen.

[ZeroLord]

ist dieses problem noch da und falls ja gibt es dafür bereits einen fix (per spine wär am besten)
wollte hiver ma wieder anfangen hab aber gleich am anfang gestoppt als ich dieses thema hier gelesen hatte und wollte nicht 100h investiren nur um falls ein hotfix noch kommen sollte nochmal anfangen zu müssen.

weiß wirklich niemand ob das problem berits gefixt ist ?

[Road-runner]

Es ist noch nicht gefixt. Zumindest ist es für mich reproduzierbar noch vorhanden.

[ZeroLord]

Es ist noch nicht gefixt. Zumindest ist es für mich reproduzierbar noch vorhanden.

war bisher nicht bei lutero also heißt das, das der bug alleverkaufsobjecte auf 1g runterscrhaubt ?

[Illari]

Habe mir mal das Dialog Skript von Lutero angeschaut, doch konnte ich jetzt nichts spezifisches rauslesen was solch einen Bug verursacht. Werde mir das mal im Spiel anschauen und ggf. nen Fix erstellen. Dieser wäre zwar _decompiled da ich in meinem LHiver etliche änderungen vorgenommen habe, doch vllt kann es ja dann jemand brauchen.

Hier aber mal das Skript falls jemand schneller ist im lesen und erkennen

instance DIA_Lutero_EXIT(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 999;
    condition = DIA_Lutero_EXIT_Condition;
    information = DIA_Lutero_EXIT_Info;
    permanent = TRUE;
    description = Dialog_Ende;
};


func int DIA_Lutero_EXIT_Condition()
{
    return TRUE;
};

func void DIA_Lutero_EXIT_Info()
{
    AI_StopProcessInfos (self);
    if ((Lutero_Krallen == LOG_Running) && (MIS_Fajeth_Kill_Snapper == LOG_SUCCESS) && (Npc_KnowsInfo (other, DIA_Bilgot_KNOWSLEADSNAPPER) == FALSE))
    {
        Lutero_Krallen = LOG_OBSOLETE;
        B_CheckLog ();
    };
};


instance DIA_Lutero_Hallo(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 5;
    condition = DIA_Lutero_Hallo_Condition;
    information = DIA_Lutero_Hallo_Info;
    permanent = FALSE;
    important = TRUE;
};


func int DIA_Lutero_Hallo_Condition()
{
    if (((other.guild != GIL_NONE) || (other.guild != GIL_NOV)) && Npc_IsInState (self, ZS_Talk))
    {
        return TRUE;
    };
};

func void DIA_Lutero_Hallo_Info()
{
    AI_Output (self, other, "DIA_Lutero_Hallo_13_00");    //Mein Name ist Lutero. Ich handle mit den verschiedensten Sachen.
    AI_Output (other, self, "DIA_Lutero_Hallo_15_01");    //Welche Ware bietest du an?
    AI_Output (self, other, "DIA_Lutero_Hallo_13_02");    //Nun, vor allem seltene und ausgefallene Dinge. Bisher ist es mir immer gelungen, die Wünsche meiner Kunden zu erfüllen.
    Log_CreateTopic (TOPIC_CityTrader, LOG_NOTE);
    B_LogEntry (TOPIC_CityTrader, "Lutero handelt mit ausgefallenen und seltenen Gegenständen im oberen Viertel.");
};


instance DIA_Lutero_GetLost(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 5;
    condition = DIA_Lutero_GetLost_Condition;
    information = DIA_Lutero_GetLost_Info;
    permanent = FALSE;
    important = TRUE;
};


func int DIA_Lutero_GetLost_Condition()
{
    if (((other.guild == GIL_NONE) || (other.guild == GIL_NOV)) && Npc_IsInState (self, ZS_Talk))
    {
        return TRUE;
    };
};

func void DIA_Lutero_GetLost_Info()
{
    if (other.guild == GIL_NONE)
    {
        AI_Output (self, other, "DIA_Lutero_GetLost_13_00");    //Verschwinde Bursche! Hast du nichts zu tun? Dann such dir Arbeit - aber woanders!
    }
    else
    {
        AI_Output (self, other, "DIA_Lutero_GetLost_13_01");    //Was willst du, Novize? Solltest du nicht im Kloster sein?
    };
    AI_StopProcessInfos (self);
};


instance DIA_Lutero_Snapper(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 5;
    condition = DIA_Lutero_Snapper_Condition;
    information = DIA_Lutero_Snapper_Info;
    permanent = FALSE;
    important = TRUE;
    description = "Für Innos.";
};


func int DIA_Lutero_Snapper_Condition()
{
    if (kapitel >= 2)
    {
        return TRUE;
    };
};

func void DIA_Lutero_Snapper_Info()
{
    AI_Output (self, other, "DIA_Lutero_Snapper_13_00fix");    //Für Innos.
    AI_Output (other, self, "DIA_Lutero_Snapper_15_00");    //Suchst du bestimmte Gegenstände?
    AI_Output (self, other, "DIA_Lutero_Snapper_13_01");    //Ja, für meinen derzeitigen Auftrag benötige ich die Krallen eines Snappers.
    AI_Output (self, other, "DIA_Lutero_Snapper_13_02");    //Aber keine einfachen Krallen. Es muss schon was Besonderes sein. Die Krallen einer mächtigen Bestie, die viele Männer getötet hat, oder etwas Derartiges.
    AI_Output (other, self, "DIA_Lutero_Snapper_15_03");    //Wo finde ich Snapper?
    AI_Output (self, other, "DIA_Lutero_Snapper_13_04");    //Es gibt ein paar hier auf der Insel, die meisten hausen jedoch im Minental.
    AI_Output (other, self, "DIA_Lutero_Snapper_15_05");    //Und was springt für mich dabei raus?
    if ((other.guild == GIL_KDF) || (hero.guild == GIL_KDW))
    {
        AI_Output (self, other, "DIA_Lutero_Hello_13_06");    //Ich kann dir einen Runenstein besorgen.
    }
    else
    {
        AI_Output (self, other, "DIA_Lutero_Hello_13_07");    //Ich kann dir einen Ring der Unbezwingbarkeit besorgen.
    };
    AI_Output (other, self, "DIA_Lutero_Hello_15_08");    //Ich werde mal sehen, was sich machen lässt.
    Log_CreateTopic (TOPIC_Lutero, LOG_MISSION);
    Log_SetTopicStatus (TOPIC_Lutero, LOG_Running);
    B_LogEntry (TOPIC_Lutero, "Der Händler Lutero sucht nach Krallen eines besonders mächtigen Snappers.");
    Lutero_Krallen = LOG_Running;
};


instance DIA_Lutero_Kralle(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 5;
    condition = DIA_Lutero_Kralle_Condition;
    information = DIA_Lutero_Kralle_Info;
    permanent = FALSE;
    description = "Ich habe besondere Snapperkrallen für dich. ";
};


func int DIA_Lutero_Kralle_Condition()
{
    if ((Npc_HasItems (other, ItAt_ClawLeader) >= 1) && Npc_KnowsInfo (other, DIA_Lutero_Snapper))
    {
        return TRUE;
    };
};

func void DIA_Lutero_Kralle_Info()
{
    AI_Output (other, self, "DIA_Lutero_Kralle_15_00");    //Ich habe besondere Snapperkrallen für dich.
    Lutero_Krallen = LOG_SUCCESS;
    B_GivePlayerXP (XP_Ambient);
    AI_Output (self, other, "DIA_Lutero_Kralle_13_01");    //Das wird meinen Kunden freuen.
    B_GiveInvItems (other, self, ItAt_ClawLeader, 1);
    if ((other.guild == GIL_KDF) || (hero.guild == GIL_KDW))
    {
        AI_Output (self, other, "DIA_Lutero_Hello_13_02");    //Den Runenstein habe ich allerdings nicht hier. Aber ich weiß, wo er liegt.
        AI_Output (self, other, "DIA_Lutero_Hello_13_03");    //Wenn du von der Stadt zur Herberge gehst, kommst du unter einer Brücke hindurch.
        AI_Output (self, other, "DIA_Lutero_Hello_13_04");    //Dort, in einer Höhle, hat ein Freund von mir einen Runenstein in einer Truhe hinterlegt. Hier ist der Schlüssel.
        B_GiveInvItems (self, other, itke_rune_mis, 1);
    }
    else
    {
        AI_Output (self, other, "DIA_Lutero_Hello_13_05");    //Hier ist der Ring, den ich dir versprochen habe.
        B_GiveInvItems (self, other, ItRi_Prot_Total_01, 1);
    };
    Npc_RemoveInvItem(VLK_404_Lutero, ItAt_ClawLeader);
};


var int FirstNugget;

instance DIA_Lutero_Trade(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 5;
    condition = DIA_Lutero_Trade_Condition;
    information = DIA_Lutero_Trade_Info;
    permanent = TRUE;
    description = "Zeig mir deine Ware.";
    trade = TRUE;
};


func int DIA_Lutero_Trade_Condition()
{
    if (Npc_KnowsInfo (other, DIA_Lutero_Hallo))
    {
        return TRUE;
    };
};

func void DIA_Lutero_Trade_Info()
{
    AI_Output (other, self, "DIA_Lutero_Trade_15_00");    //Zeig mir deine Ware.
    if (FirstNugget == FALSE) && (Hero.level >= 10)
    {
        if (choosed_hardmode == TRUE)
        {
            CreateInvItems(self, Itmi_Nugget,2);
            CreateInvItems(self, ITMI_IRONNUGGET_ADDON,5);
            FirstNugget = TRUE;    
        }
        else if (choosed_hardmode2 == TRUE)
        {
            CreateInvItems (self, ItRi_Speed, 1);
            CreateInvItems(self, Itmi_Nugget,2);
            CreateInvItems(self, ITMI_IRONNUGGET_ADDON,5);
            FirstNugget = TRUE;    
        };
    };
    B_GiveTradeInv (self);
};


instance DIA_Lutero_Trading(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 900;
    condition = DIA_Lutero_Trading_Condition;
    information = DIA_Lutero_Trading_Info;
    permanent = FALSE;
    description = "Kannst du mir etwas beibringen?";
};


func int DIA_Lutero_Trading_Condition()
{
    if ((Choosed_Hardmode == TRUE) || (Choosed_Hardmode2 == TRUE))
    {
        return TRUE;
    };
};

func void DIA_Lutero_Trading_Info()
{
    AI_Output (other, self, "DIA_DiegoOw_Teach_15_00");        //Kannst du mir etwas beibringen?
    AI_Output (self, other, "DIA_Lutero_Trading_08_03");    //Ich kann dir etwas über das Feilschen erzählen - was in besonderen Notlagen eine große Hilfe sein kann.
    AI_Output (self, other, "DIA_Lutero_Trading_08_04");    //Doch dafür wirst du auch dein Handelsgeschick trainieren müssen.
    AI_Output (self, other, "DIA_Lutero_Trading_08_05");    //Auch das kannst du bei mir lernen.
    AI_Output (self, other, "DIA_Lutero_Trading_08_06");    //Je geschickter du die Händler in verwirrende Handelsgespräche hineinzerrst, desto besser werden deine Verkaufspreise sein.
    AI_Output (self, other, "DIA_Lutero_Trading_08_07");    //Lerne und übe stets fleißig, um deine Goldsorgen ein für allemal los zu sein... (lacht)
    AI_Output (self, other, "DIA_Lutero_Trading_08_08");    //Wir können mit all dem anfangen, sobald du bereit dafür bist.
    Lutero_TeachTrade = TRUE;
    Log_CreateTopic (TOPIC_ALL_TALENTS, LOG_NOTE);
    B_LogEntry (TOPIC_ALL_TALENTS, "Lutero kann mir dabei helfen, bei den Händlern bessere Verkaufspreise zu erzielen und mein Handelsgeschick zu verbessern.");
    AI_StopProcessInfos(self);
};


instance DIA_Lutero_TeachTrade(C_Info)
{
    npc = vlk_404_Lutero;
    nr = 901;
    condition = DIA_Lutero_TeachTrade_Condition;
    information = DIA_Lutero_TeachTrade_Info;
    permanent = TRUE;
    description = "Besser feilschen lernen (5 LP)";
};


func int DIA_Lutero_TeachTrade_Condition()
{
    if (Npc_GetTalentSkill (other, NPC_TALENT_TRADE) == 0) && (Lutero_TeachTrade == TRUE)
    {
        return TRUE;
    };
};

func void DIA_Lutero_TeachTrade_Info()
{
    if (B_TeachTrade (self, other, NPC_TALENT_TRADE))
    {
        AI_Output (other, self, "DIA_Lutero_TeachTrade_15_00");    //Bring mir was über das Feilschen bei.
        AI_Output (self, other, "DIA_Lutero_TeachTrade_08_01");    //Du wirst beim Handeln bald bemerken, dass du bessere Preise bekommst.
        AI_Output (self, other, "DIA_Lutero_TeachTrade_08_02");    //Ab morgen solltest du eine Verbesserung spüren können.
        Lutero_TeachDEX = TRUE;
        Trade_One = TRUE;
        AI_Printscreen ("1. STUFE BEIM FEILSCHEN ERREICHT!", -1, YPOS_XPGained, Font_ScreenSmall, 4);
        B_LogEntry (TOPIC_ALL_TALENTS,"Ich habe etwas über's Feilschen gelernt (1.Stufe). Damit sollte ich schon bessere Preise bei den Händlern erhalten.");
    };
    AI_StopProcessInfos(self);
};


instance DIA_Lutero_TEACH_TradingDEx(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 902;
    condition = DIA_Lutero_TEACH_TradingDEx_Condition;
    information = DIA_Lutero_TEACH_TradingDEx_Info;
    permanent = TRUE;
    description = "Handelsgeschick verbessern";
};


func int DIA_Lutero_TEACH_TradingDEx_Condition()
{
    if (Lutero_TeachDEX == TRUE) && (Max_TradingDexLearn == FALSE)
    {
        return TRUE;
    };
};

func void DIA_Lutero_TEACH_TradingDEx_Info()
{
    AI_Output (other, self, "DIA_Cassia_TEACH_15_00");    //Ich will geschickter werden.
    Info_ClearChoices (DIA_Lutero_TEACH_TradingDEx);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, Dialog_Back, DIA_Lutero_TEACH_TradingDEx_BACK);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, B_BuildLearnString (PRINT_LearnTradingDEX1, B_GetLearnCosttalent (other, NPC_TALENT_TRADINGDEX,1)), DIA_Lutero_TEACH_TradingDEx_1);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, B_BuildLearnString (PRINT_LearnTradingDEX5, B_GetLearnCosttalent (other, NPC_TALENT_TRADINGDEX,5)), DIA_Lutero_TEACH_TradingDEx_5);
};

func void DIA_Lutero_TEACH_TradingDEx_BACK()
{
    if (Npc_GetTalentSkill(hero,NPC_TALENT_TRADINGDEX) >= 5) &&  (ATR_TRADINGDEX < 10) && (SecondStep_Trade == False)
    {
        Trade_One = FALSE;
        Trade_Two = TRUE;
        SecondStep_Trade = TRUE;
        AI_Printscreen ("2. STUFE BEIM FEILSCHEN ERREICHT!", -1, YPOS_XPGained, Font_ScreenSmall, 4);
        B_LogEntry (TOPIC_ALL_TALENTS,"Ich habe etwas über's Feilschen gelernt (2.Stufe).");
    };
    if (Npc_GetTalentSkill(hero,NPC_TALENT_TRADINGDEX) >= 10)
    {
        AI_Printscreen ("MAXIMALES HANDELSGESCHICK ERREICHT!", -1, YPOS_LevelUp, Font_ScreenSmall, 3);
        Trade_Two = False;
        Trade_Three = TRUE;
        AI_Output (self, other, "DIA_Lutero_TEACH_TradingDEx_08_01");    //Dein Handelsgeschick ist mittlerweile ziemlich gut geworden. 
        AI_Output (self, other, "DIA_Lutero_TEACH_TradingDEx_08_02");    //Ich denke, damit solltest du nun bei den Händlern keine Verkaufsprobleme mehr haben.
        AI_Wait (self,1);
        AI_Printscreen ("3. UND LETZTE STUFE BEIM FEILSCHEN ERREICHT!", -1, YPOS_XPGained, Font_ScreenSmall, 4);
        Snd_Play ("LevelUp");
        Max_TradingDexLearn = TRUE;
        B_LogEntry (TOPIC_ALL_TALENTS,"Ich habe mein Verkaufstalent gemeistert (3.Stufe).");
    };
    Info_ClearChoices (DIA_Lutero_TEACH_TradingDEx);
};

func void DIA_Lutero_TEACH_TradingDEx_1()
{
    B_TeachTradingDex (self, other, NPC_TALENT_TRADINGDEX, 1);
    if (Npc_GetTalentSkill(hero,NPC_TALENT_TRADINGDEX) >= 10) &&  (ATR_TRADINGDEX < 20) && (SecondStep_Trade == False)
    {
        Trade_One = FALSE;
        Trade_Two = TRUE;
        SecondStep_Trade = TRUE;
        AI_Printscreen ("2. STUFE BEIM FEILSCHEN ERREICHT!", -1, YPOS_XPGained, Font_ScreenSmall, 4);
        B_LogEntry (TOPIC_ALL_TALENTS,"Ich habe etwas über's Feilschen gelernt (2.Stufe).");
    };
    print_lpcounter_hdex_none (ATR_STAMINA, ATR_STAMINA_MAX, "", 42, 97);
    print_lpcounter_hdex (ATR_STAMINA, ATR_STAMINA_MAX, "", 51, 80);
    Info_ClearChoices (DIA_Lutero_TEACH_TradingDEX);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, Dialog_Back, DIA_Lutero_TEACH_TradingDEx_BACK);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, B_BuildLearnString (PRINT_LearnTradingDEX1, B_GetLearnCosttalent (other, NPC_TALENT_TRADINGDEX,1)), DIA_Lutero_TEACH_TradingDEx_1);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, B_BuildLearnString (PRINT_LearnTradingDEX5, B_GetLearnCosttalent (other, NPC_TALENT_TRADINGDEX,5)), DIA_Lutero_TEACH_TradingDEx_5);
};

func void DIA_Lutero_TEACH_TradingDEx_5()
{
    B_TeachTradingDex (self, other, NPC_TALENT_TRADINGDEX, 5);
    if (Npc_GetTalentSkill(hero,NPC_TALENT_TRADINGDEX) >= 10) &&  (ATR_TRADINGDEX < 20) && (SecondStep_Trade == False)
    {
        Trade_One = FALSE;
        Trade_Two = TRUE;
        SecondStep_Trade = TRUE;
        AI_Printscreen ("2. STUFE BEIM FEILSCHEN ERREICHT!", -1, YPOS_XPGained, Font_ScreenSmall, 4);
        B_LogEntry (TOPIC_ALL_TALENTS,"Ich habe etwas über's Feilschen gelernt (2.Stufe).");
    };
    print_lpcounter_hdex_none (ATR_STAMINA, ATR_STAMINA_MAX, "", 42, 97);
    print_lpcounter_hdex (ATR_STAMINA, ATR_STAMINA_MAX, "", 51, 80);
    Info_ClearChoices (DIA_Lutero_TEACH_TradingDEX);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, Dialog_Back, DIA_Lutero_TEACH_TradingDEx_BACK);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, B_BuildLearnString (PRINT_LearnTradingDEX1, B_GetLearnCosttalent (other, NPC_TALENT_TRADINGDEX,1)), DIA_Lutero_TEACH_TradingDEx_1);
    Info_AddChoice (DIA_Lutero_TEACH_TradingDEx, B_BuildLearnString (PRINT_LearnTradingDEX5, B_GetLearnCosttalent (other, NPC_TALENT_TRADINGDEX,5)), DIA_Lutero_TEACH_TradingDEx_5);
};

instance DIA_Lutero_PICKPOCKET(C_Info)
{
    npc = VLK_404_Lutero;
    nr = 900;
    condition = DIA_Lutero_PICKPOCKET_Condition;
    information = DIA_Lutero_PICKPOCKET_Info;
    permanent = TRUE;
    description = Pickpocket_60;
};


func int DIA_Lutero_PICKPOCKET_Condition()
{
    return C_Beklauen (58, 65);
};

func void DIA_Lutero_PICKPOCKET_Info()
{
    Info_ClearChoices (DIA_Lutero_PICKPOCKET);
    Info_AddChoice (DIA_Lutero_PICKPOCKET, Dialog_Back, DIA_Lutero_PICKPOCKET_BACK);
    Info_AddChoice (DIA_Lutero_PICKPOCKET, DIALOG_PICKPOCKET, DIA_Lutero_PICKPOCKET_DoIt);
};

func void DIA_Lutero_PICKPOCKET_DoIt()
{
    B_Beklauen ();
    Info_ClearChoices (DIA_Lutero_PICKPOCKET);
};

func void DIA_Lutero_PICKPOCKET_BACK()
{
    Info_ClearChoices (DIA_Lutero_PICKPOCKET);
};

[Tentarr]

Hat ja nicht viele Variablen, möchte wer einen savegame hochstellen, dann kann man das ja überpürfen.

Vermutlich wird eine der Bedingungen nicht erfüllt.

[ZeroLord]

lutero soll ja auch den ring der geschwindigkeit verkaufen doch bei ihm seh nichts der gleichen
weiß jemand ob das in einer alten version auch so war oder ist das auch ein bug ?

[Tentarr]

Ich bitte mich immr noch an, einen save anzuschauen und nach dem fehler zu suchen, muss mir halt einer einen save hochladen, da ich l`hiver grad nicht installiert habe und beruflich unterwegs bin.

[Road-runner]

mir ist beim zocken gerade gekommen, dass es ggf an die quest mit den snapperkrallen gebunden ist.
Kam bisher nicht dazu das zu probieren. ggf. hat ja jemand Zeit.
Und wenn ich zeit finde schaue ich mir den Code nochmal genauer an.